<%
Const cdoSendUsingMethod = _
"http://schemas.microsoft.com/cdo/configuration/sendusing"
Const cdoSendUsingPort = 2
Const cdoSMTPServer = _
"http://schemas.microsoft.com/cdo/configuration/smtpserver"
Const cdoSMTPServerPort = _
"http://schemas.microsoft.com/cdo/configuration/smtpserverport"
Const cdoSMTPConnectionTimeout = _
"http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout"
Const cdoSMTPAccountName = _
"http://schemas.microsoft.com/cdo/configuration/smtpaccountname"
Const cdoSMTPAuthenticate = _
"http://schemas.microsoft.com/cdo/configuration/smtpauthenticate"
Const cdoBasic = 1
Const cdoSendUserName = _
"http://schemas.microsoft.com/cdo/configuration/sendusername"
Const cdoSendPassword = _
"http://schemas.microsoft.com/cdo/configuration/sendpassword"

Dim objConfig ' As CDO.Configuration
Dim objMessage ' As CDO.Message
Dim Fields ' As ADODB.Fields

' Get a handle on the config object and it's fields
Set objConfig = Server.CreateObject("CDO.Configuration")
Set Fields = objConfig.Fields

' Set config fields we care about
With Fields
.Item(cdoSendUsingMethod) = cdoSendUsingPort
.Item(cdoSMTPServer) = "mw-001.cafe24.com"
.Item(cdoSMTPServerPort) = 25
.Item(cdoSMTPAuthenticate) = cdoBasic
.Item(cdoSendUserName) = "메일아이디@메일도메인"
.Item(cdoSendPassword) = "메일비밀번호"

.Update
End With

Set objMessage = Server.CreateObject("CDO.Message")

Set objMessage.Configuration = objConfig

With objMessage
.To = "Batman <batman@gotham.com>"
.From = "Superman <superman@crypton.net>"
.Subject = "Hello, this is test mail"
.HTMLBody = "Hello"
.Send
End With

Response.Write "Success!!"

Set Fields = Nothing
Set objMessage = Nothing
Set objConfig = Nothing
%>

리셀러일 경우 .Item(cdoSMTPServer) = "mw-001.cafe24.com"
이 부분은 .Item(cdoSMTPServer) = "mail-001.리셀러도메인" 와 같이 수정해 주세요.


일반적인 CDO 메일발송과 다른점은 SMTP 인증에 관한 부분이 추가되어 있는 점입니다.
참고로 CDONTS 객체는 원격접속과 SMTP 인증기능이 없으므로 위와 같이 CDO 로 구현하셔야 합니다.